AlgoShiftRegister.vhd

Go to the documentation of this file.

-------------------------------------------------------
-------------------------------------------------------
 
library IEEE;
use IEEE.STD_LOGIC_1164.all;
use IEEE.NUMERIC_STD.all;
 
use work.DataTypes.all;
use work.AlgoDataTypes.all;
 
entity AlgoShiftRegister is
  port (CLK200 : in std_logic;
 
        IN_Load      : in  std_logic;
        IN_Data      : in  TriggerTowerMatrix;
        IN_Edge      : in  std_logic;
        IN_LeftRight : in  std_logic;
        OUT_Data     : out TriggerTowers(3*INPUT_ROWS-1 downto 0));
end AlgoShiftRegister;
 
architecture Behavioral of AlgoShiftRegister is
 
  signal ShiftTowers : TriggerTowersArray(INPUT_COLUMNS downto 0)(INPUT_ROWS-1 downto 0);
  signal LeftRight   : std_logic;
 
--  ####### attributes  ########
 attribute keep       : string ;
 attribute max_fanout : integer;
 attribute keep of       ShiftTowers : signal is "true" ;
 attribute max_fanout of ShiftTowers : signal is 30;
 
--   #######################################
begin
 
  OUT_Data <= (INPUT_ROWS-1 downto 0              => ShiftTowers(0)(INPUT_ROWS-1 downto 0),
               2*INPUT_ROWS-1 downto INPUT_ROWS   => ShiftTowers(1)(INPUT_ROWS-1 downto 0),
               3*INPUT_ROWS-1 downto 2*INPUT_ROWS => ShiftTowers(2)(INPUT_ROWS-1 downto 0));
 
  -- When eFEX is not on edge, posistion is always considered to be left
  LeftRight <= '0' when IN_Edge = '0' else IN_LeftRight;
 
  LOADER_SHIFTER : process (CLK200)
  begin
    if rising_edge(CLK200) then
      if IN_Load = '1' then
        case LeftRight is
          when '0' =>
            -- left, put zeroes in the last (high eta) column
            ShiftTowers(INPUT_COLUMNS)            <= (others => ZERO_TRIGGER_TOWER);
            ShiftTowers(INPUT_COLUMNS-1 downto 0) <= IN_Data;
 
          when others =>
            -- right, put zeroes in the first (small eta) column            
            ShiftTowers(INPUT_COLUMNS downto 1) <= IN_Data;
            ShiftTowers(0)                      <= (others => ZERO_TRIGGER_TOWER);
        end case;
 
      else
        -- shift data
        ShiftTowers(INPUT_COLUMNS)            <= (others => ZERO_TRIGGER_TOWER);
        ShiftTowers(INPUT_COLUMNS-1 downto 0) <= ShiftTowers(INPUT_COLUMNS downto 1);
      end if;
    end if;
  end process;
 
end Behavioral;