efex_packet_mux.vhd

Go to the documentation of this file.

 
 
library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
 
LIBRARY infrastructure_lib;
use infrastructure_lib.packet_mux_type.all;
 
entity efex_packet_mux is
  generic(NSRC: positive := 4);
  port (
    clk                 : in std_logic;
    rst_clk             : in std_logic;
-- Shelf and eFEX number (for error recovery trailer)
    eFEX_number         : in std_logic_vector(7 downto 0);
    pause               : in std_logic := '0';
    packet_mux_enabled  : IN std_logic_vector(NSRC-1 downto 0);
    packet_mux_reset    : IN std_logic_vector(NSRC-1 downto 0);
    packet_mux_source   : OUT std_logic_vector(3 downto 0);
    packet_mux_data     : IN packet_data_array(NSRC-1 downto 0);
    packet_mux_valid    : IN std_logic_vector(NSRC-1 downto 0);
    packet_mux_last     : IN std_logic_vector(NSRC-1 downto 0);
    packet_mux_ready    : OUT std_logic_vector(NSRC-1 downto 0);
    packet_data         : OUT std_logic_vector (63 DOWNTO 0) ;
    packet_valid        : OUT std_logic;
    packet_last         : OUT std_logic;
    packet_ready        : IN std_logic
  );
end efex_packet_mux;
 
architecture rtl of efex_packet_mux is
 
  TYPE STATE_TYPE IS (
    running,
    starting,
    hunting
  );
 
    signal state_sig: STATE_TYPE := hunting;
    signal src, hunting_src: unsigned(3 downto 0) := (Others => '0'); -- Up to 14 sources (last two are special)...
    signal sel, hunting_sel: integer range 0 to NSRC+1 := 0;
    signal active: std_logic;
    signal packet_mux_data_sig: packet_data_array(NSRC+1 downto 0);
    signal packet_mux_valid_sig, packet_mux_last_sig, packet_mux_reset_sig: std_logic_vector(NSRC+1 downto 0);
    signal packet_mux_ready_sig, packet_mux_enabled_sig: std_logic_vector(NSRC-1 downto 0);
 
begin
 
    sel <= to_integer(src);
    hunting_sel <= to_integer(hunting_src);
    packet_mux_source <= std_logic_vector(src);
 
    packet_mux_data_sig(NSRC+1) <= (Others => '0'); -- dummy source for the MUX whilst hunting
    packet_mux_data_sig(NSRC) <= x"00000028000" & eFEX_number & x"000"; -- Assert Corrective Trailer and Protocol Error in recovery trailer
    packet_mux_data_sig(NSRC-1 downto 0) <= packet_mux_data;
    packet_mux_valid_sig <= "01" & packet_mux_valid;
    packet_mux_last_sig <= "01" & packet_mux_last;
    packet_mux_reset_sig <= "00" & packet_mux_reset;
    packet_mux_enabled_sig <= packet_mux_enabled;
    packet_mux_ready <= packet_mux_ready_sig;
 
    process(clk)
    begin
        if rising_edge(clk) then
            if rst_clk = '1' then
                active <= '0';
                src <= (others => '0');
                hunting_src <= (others => '0');
                state_sig <= hunting;
            else
                Case state_sig is
                When running =>
-- Remember that we could be in error recovery so sel might be equal to NSRC...
                    if (packet_mux_last_sig(sel) = '1') and (packet_ready = '1') then  -- End of Frame...
                        active <= '0';  -- disable control logic
                        src <= to_unsigned(NSRC+1, 4);  -- park MUX on dummy input
                        state_sig <= hunting;   -- switch to search for next packet
                    elsif (packet_mux_reset_sig(sel) = '1') then  -- Error recovery, switch to sending corrective trailer...
                        src <= to_unsigned(NSRC, 4);
                    end if;
                When starting =>
                    active <= '1';
                    state_sig <= running;
                When Others => -- hunting...
                    if (pause = '1') then
                        null;
-- Activate if packet ready and not being reset...
                    elsif (packet_mux_valid_sig(hunting_sel) = '1') and (packet_mux_enabled_sig(hunting_sel) = '1') and (packet_mux_reset_sig(hunting_sel) = '0') then
                        src <= hunting_src;
                        state_sig <= starting;
-- Switch to 0 if packet available there!
                    elsif (packet_mux_valid_sig(0) = '1') and (packet_mux_enabled_sig(0) = '1') and (packet_mux_reset_sig(0) = '0') then
                        src <= (others => '0');
                        state_sig <= starting;
-- Otherwise Round Robin over the real inputs
                    elsif (hunting_src /= (NSRC-1)) then
                        hunting_src <= hunting_src + 1;
                    else
                        hunting_src <= to_unsigned(1, 4);   -- We always check 0 so start at 1 for the round robin
                    end if;
                end case;
            end if;
        end if;
    end process;
 
-- mask signal when hunting for data...
    packet_valid <= packet_mux_valid_sig(sel) when active = '1' else '0';
    packet_data <= packet_mux_data_sig(sel);
    packet_last <= packet_mux_last_sig(sel);
 
    ackgen: for i in NSRC-1 downto 0 generate
    begin
        packet_mux_ready_sig(i) <= packet_ready when (sel = i) and (active = '1') else '0';
    end generate;
 
end rtl;